{
  pkgs,
  config,
  lib,
  ...
}: let
  service = "kiwix";
  cfg = config.homelab.${service};
  sec = config.sops.secrets;
  homelab = config.homelab;
in {
  options.homelab.${service} = {
    enable = lib.mkEnableOption "enables ${service}";
    # set port options
    port = lib.mkOption {
      type = lib.types.int;
      default = 7730;
      description = "set port for ${service} (default: ${toString cfg.port}";
    };
    url = lib.mkOption {
      type = lib.types.str;
      default = "${service}.${homelab.base_domain}";
      description = "set domain for ${service}";
    };
    data_dir = lib.mkOption {
      type = lib.types.str;
      default = "/var/lib/${service}";
      description = "set data directory for ${service}";
    };
    ids = lib.mkOption {
      type = lib.types.int;
      default = cfg.port;
      description = "set uid and pid of ${service} user (matches port by default)";
    };
    backup = lib.mkOption {
      type = lib.types.bool;
      default = true;
      description = "enable backups for ${service}";
    };
    motd = lib.mkOption {
      type = lib.types.nullOr lib.types.str;
      default = "kiwix-serve";
    };
  };

  config = lib.mkIf cfg.enable {
    # declare ${service} group
    users.groups.${service} = {
      gid = lib.mkForce cfg.ids;
    };

    # declare ${service} user
    users.users.${service} = {
      description = "${service} server user";
      uid = lib.mkForce cfg.ids;
      isSystemUser = true;
      home = cfg.data_dir;
      createHome = true;
      group = service;
      extraGroups = ["media"];
    };

    # helpful and for scripts
    environment.systemPackages = with pkgs; [kiwix-tools];

    # enable the ${service} service
    services.kiwix-serve = {
      enable = true;
      openFirewall = true;
      port = cfg.port;
      user = service;
      group = service;
      libraryPath = "${cfg.data_dir}/library.xml";
      extraArgs = {
      };
    };

    # override umask to make permissions work out
    systemd.services.${service}.serviceConfig = {
      UMask = lib.mkForce "0007";
      User = service;
      Group = service;
    };

    # add to caddy for reverse proxy
    services.caddy.virtualHosts."${cfg.url}" = {
      serverAliases = ["${service}.${homelab.public_domain}"];
      # use explicitly defined tls cert
      # tls /etc/ssl/blakedheld.xyz.crt /etc/ssl/blakedheld.xyz.key
      extraConfig = ''
        tls internal
        reverse_proxy 127.0.0.1:${toString cfg.port}
      '';
    };

    # add to glance (local service)
    homelab.glance.links.nomad = [
      {
        title = service;
        url = "https://${cfg.url}";
        error-url = "http://${homelab.host_ip}:${toString cfg.port}";
        check-url = "http://${homelab.host_ip}:${toString cfg.port}";
        icon = "di:${service}";
      }
    ];

    #    sops.secrets = {
    #      "${service}_" = {
    #        owner = ;
    #        group = ;
    #      };
    #    };

    # add to backups
    homelab.backups.baks = {
      ${service} = {
        paths = [cfg.data_dir];
      };
    };
  };
}