{
  pkgs,
  config,
  lib,
  ...
}: let
  service = "ollama";
  cfg = config.homelab.${service};
  homelab = config.homelab;
in {
  options.homelab.${service} = {
    enable = lib.mkEnableOption "enables ${service}";

    # set port options
    port = lib.mkOption {
      type = lib.types.int;
      default = 7710;
      description = "set port for ${service} (default: ${toString cfg.port}";
    };
    url = lib.mkOption {
      type = lib.types.str;
      default = "ollama.${homelab.base_domain}";
      description = "set domain for ${service}";
    };
    data_dir = lib.mkOption {
      type = lib.types.str;
      default = "/var/lib/${service}";
      description = "set data directory for ${service}";
    };
    ids = lib.mkOption {
      type = lib.types.int;
      default = cfg.port;
      description = "set uid and pid of ${service} user (matches port by default)";
    };
    backup = lib.mkOption {
      type = lib.types.bool;
      default = true;
      description = "enable backups for ${service}";
    };
    motd = lib.mkOption {
      type = lib.types.nullOr lib.types.str;
      default = service;
    };
  };

  config = lib.mkIf cfg.enable {
    # declare ${service} group
    users.groups.${service} = {gid = lib.mkForce cfg.ids;};

    # declare ${service} user
    users.users.${service} = {
      description = lib.mkForce "${service} server user";
      uid = lib.mkForce cfg.ids;
      isSystemUser = true;
      shell = pkgs.bash;
      home = cfg.data_dir;
      createHome = true;
      group = service;
      extraGroups = [];
    };

    # declare the gitea service
    services.${service} = {
      enable = true;
      host = "0.0.0.0";
      port = cfg.port;
      openFirewall = true;
      syncModels = true;
      loadModels = [
        "deepseek-r1:7b"
        "deepseek-r1:14b"
      ];
    };

    # override umask to make permissions work out
    systemd.services.${service}.serviceConfig = {
      UMask = lib.mkForce "0007";
    };

    # open firewall
    networking.firewall.allowedTCPPorts = [cfg.port];

    services.caddy.virtualHosts."${cfg.url}" = {
      extraConfig = ''
        tls internal
        reverse_proxy localhost:${toString cfg.port} {
        }
      '';
    };

    # add to backups
    homelab.backups.baks = {
      ${service} = {
        paths = [cfg.data_dir "/var/lib/private"];
      };
    };
  };
}