{
  pkgs,
  config,
  lib,
  ...
}: let
  service = "navidrome";
  cfg = config.homelab.${service};
  homelab = config.homelab;
in {
  options.homelab.${service} = {
    enable = lib.mkEnableOption "enables ${service}";

    # set port options
    port = lib.mkOption {
      type = lib.types.int;
      default = 7108;
      description = "set port for ${service} (default: ${toString cfg.port}";
    };
    url = lib.mkOption {
      type = lib.types.str;
      default = "music.${homelab.base_domain}";
      description = "set domain for ${service}";
    };
    data_dir = lib.mkOption {
      type = lib.types.str;
      default = "/var/lib/${service}";
      description = "set data directory for ${service}";
    };
    ids = lib.mkOption {
      type = lib.types.int;
      default = cfg.port;
      description = "set uid and pid of ${service} user (matches port by default)";
    };
    backup = lib.mkOption {
      type = lib.types.bool;
      default = true;
      description = "enable backups for ${service}";
    };
    motd = lib.mkOption {
      type = lib.types.nullOr lib.types.str;
      default = service;
    };
  };

  config = lib.mkIf cfg.enable {
    # declare ${service} group
    users.groups.${service} = {gid = lib.mkForce cfg.ids;};

    # declare ${service} user
    users.users.${service} = {
      description = "${service} server user";
      uid = lib.mkForce cfg.ids;
      isSystemUser = true;
      #      home = cfg.data_dir;
      createHome = true;
      group = service;
      extraGroups = ["media"];
    };

    # enable the ${service} service
    services.${service} = {
      enable = true;
      openFirewall = true;
      user = service;
      group = service;
      #      plugins = [
      #      ];
      environmentFile = "${cfg.data_dir}/navidrome/plugins";
      settings = {
        Address = "0.0.0.0";
        Port = cfg.port;
        MusicFolder = "/holocron/media/music";
        EnableInsightsCollector = false;
        LyricsPriority = "nd-lyrics";
        Plugins = {
          Enabled = true;
          #Folder = lib.mkForce "${cfg.data_dir}/plugins";
        };
      };
    };

    # override umask to make permissions work out
    systemd.services.${service}.serviceConfig = {
      UMask = lib.mkForce "0007";
      EnvironmentFile = "${cfg.data_dir}/navidrome.env";
    };

    # add to caddy for reverse proxy
    services.caddy.virtualHosts."${cfg.url}" = {
      #serverAliases = ["abs.${homelab.public_domain}"];
      extraConfig = ''
        tls internal
        reverse_proxy 127.0.0.1:${toString cfg.port} {
        }
      '';
    };

    # add to glance public service
    homelab.glance.links.mediastack = [
      {
        title = service;
        url = "https://music.${homelab.base_domain}";
        error-url = "http://${homelab.host_ip}:${toString cfg.port}";
        check-url = "http://${homelab.host_ip}:${toString cfg.port}";
        icon = "di:${service}";
      }
    ];

    # add to backups
    homelab.backups.baks = {
      ${service} = {paths = [cfg.data_dir];};
    };
  };
}