{
  pkgs,
  config,
  lib,
  ...
}: let
  service = "vaultwarden";
  cfg = config.homelab.${service};
  sec = config.sops.secrets;
  homelab = config.homelab;
  domain = "https://pass.holocron.blue";
in {
  options.homelab.${service} = {
    enable = lib.mkEnableOption "enables ${service}";

    # set port options
    port = lib.mkOption {
      type = lib.types.int;
      default = 7701;
      description = "set port for ${service} (default: ${toString cfg.port}";
    };
    url = lib.mkOption {
      type = lib.types.str;
      default = "pass.${homelab.base_domain}";
      description = "set domain for ${service}";
    };
    data_dir = lib.mkOption {
      type = lib.types.str;
      default = "/var/lib/${service}";
      description = "set data directory for ${service}";
    };
    ids = lib.mkOption {
      type = lib.types.int;
      default = cfg.port;
      description = "set uid and pid of ${service} user (matches port by default)";
    };
    backup = lib.mkOption {
      type = lib.types.bool;
      default = true;
      description = "enable backups for ${service}";
    };
    motd = lib.mkOption {
      type = lib.types.nullOr lib.types.str;
      default = service;
    };
  };

  config = lib.mkIf cfg.enable {
    # declare ${service} group
    users.groups.${service} = {gid = lib.mkForce cfg.ids;};

    # declare ${service} user
    users.users.${service} = {
      description = "${service} server user";
      uid = lib.mkForce cfg.ids;
      isSystemUser = true;
      home = cfg.data_dir;
      createHome = true;
      group = service;
      extraGroups = [];
    };

    # enable the vaultwarden service
    services.${service} = {
      enable = true;
      package = pkgs.unstable.vaultwarden;
      config = {
        DOMAIN = "pass.${homelab.public_domain}";
        IP_HEADER = "X-Forwarded-For";
        ROCKET_ADDRESS = "0.0.0.0";
        ROCKET_PORT = cfg.port;
        SIGNUPS_ALLOWED = true;
        ADMIN_TOKEN = "$argon2id$v=19$m=19456,t=2,p=1$YXJKa0ZubE9OZkp5c0NlMC95TFhBcFh3K1VsUkk1bElTSFJkbmdYdmp4az0$bsLT8/18BmexUbzqlHp0S4aoIxi6bYxl0IY0EweF5N4";
        EXPERIMENTAL_CLIENT_FEATURE_FLAGS = "ssh-key-vault-item";
      };
    };

    # override umask to make permissions work out
    systemd.services.${service}.serviceConfig = {UMask = lib.mkForce "0007";};

    # open firewall
    networking.firewall.allowedTCPPorts = [cfg.port];

    # add to caddy for reverse proxy
    services.caddy.virtualHosts."${cfg.url}" = {
      serverAliases = ["pass.${homelab.public_domain}"];
      extraConfig = ''
        tls internal
        reverse_proxy 127.0.0.1:${toString cfg.port}
      '';
    };

    # add to glance
    homelab.glance.links.services = [
      {
        title = service;
        url = "https://pass.${homelab.public_domain}";
        error-url = "http://${homelab.host_ip}:${toString cfg.port}";
        check-url = "http://${homelab.host_ip}:${toString cfg.port}";
        icon = "di:${service}";
      }
    ];

    sops.secrets = {
      "${service}_admin_token" = {
        owner = "${service}";
        group = "${service}";
      };
    };

    # add to backups
    homelab.backups.baks = {
      ${service} = {paths = [cfg.data_dir];};
    };
  };
}