test restructure

2026-05-02 17:43:53 -05:00
parent 6fdc826b2a
commit 7302648b57
59 changed files with 3151 additions and 25 deletions
@@ -0,0 +1,129 @@
+{ pkgs, config, lib, ... }:
+
+let
+  service = "caddy";
+  cfg = config.homelab.${service};
+  sec = config.sops.secrets;
+  homelab = config.homelab;
+in
+{
+  options.homelab.${service} = {
+    enable = lib.mkEnableOption "enables ${service}";
+
+    # set port options
+    data_dir = lib.mkOption {
+      type = lib.types.str;
+      default = "/var/lib/${service}";
+      description = "set data directory for ${service}";
+    };
+    keys = lib.mkOption {
+      type = lib.types.bool;
+      default = true;
+      description = "host keys directory";
+    };
+    backup = lib.mkOption {
+      type = lib.types.bool;
+      default = true;
+      description = "enable backups for ${service}";
+    };
+    motd = lib.mkOption {
+      type = lib.types.nullOr lib.types.str;
+      default = service;
+    };
+  };
+
+  config = lib.mkIf cfg.enable {
+    
+    # declare ${service} group
+    users.groups.${service} = {};
+
+    # declare ${service} user
+    users.users.${service} = {
+      description = "${service} server user";
+      isSystemUser = true;
+      home = cfg.data_dir;
+      createHome = true;
+      group = service;
+      extraGroups = [];
+    };
+
+    # enable the ${service} service
+    services.${service} = {
+      enable = true;
+      user = service;
+      group = service;
+      dataDir = cfg.data_dir;
+      email = "me@blakedheld.xyz";
+      globalConfig = ''
+        auto_https ignore_loaded_certs
+      '';
+      
+      virtualHosts."keys.${homelab.base_domain}" =  lib.mkIf cfg.keys {
+        serverAliases = [ "keys.${homelab.public_domain}" ];
+        extraConfig = ''
+            tls internal
+            root /var/www/keys
+            file_server browse
+        '';
+      };
+    };
+
+    # enable acme for auto ssl certs with lets encrypt
+    security.acme = {
+      acceptTerms = true;
+      defaults.email = "me@blakedheld.xyz";
+    };
+
+    # override umask to make permissions work out
+    systemd.services.${service}.serviceConfig = {
+      UMask = lib.mkForce "0007";
+    };
+
+    # open firewall
+    networking.firewall.allowedTCPPorts = [ 80 443 ];
+
+    sops.secrets = {
+      "ssl_blakedheld_crt" = {
+        owner = "caddy";
+        group = "caddy";
+        path = "/etc/ssl/blakedheld.xyz.crt";
+      };
+      "ssl_blakedheld_key" = {
+        owner = "caddy";
+        group = "caddy";
+        path = "/etc/ssl/blakedheld.xyz.key";
+      };
+      "klefki_pub.asc" = {
+        owner = "caddy";
+        group = "caddy";
+        path = "/var/www/keys/klefki_pub.asc";
+      };
+      "caddy_root.crt" = {
+        owner = "caddy";
+        group = "caddy";
+        path = "/var/www/keys/caddy_root.crt";
+      };
+    };
+ 
+  environment.etc."caddy/browse.html".text = ''
+    <!DOCTYPE html>
+    <html>
+      <head>
+        <meta charset="utf-8">
+        <title>{{html .Name}}</title>
+        <style>
+          footer { display: none !important; }
+        </style>
+      </head>
+      <body>
+        {{template "listing" .}}
+      </body>
+    </html>
+  '';
+
+    # add to backups
+   homelab.backups.baks = {
+      ${service} = { paths = [ cfg.data_dir ]; };
+    };
+  };
+}